Algebra

com[X_,Y_]:=X.Y-Y.X;

Generators

T={I PauliMatrix[1], I PauliMatrix[2],I PauliMatrix[3]}

Tp=(1/2)(T[[2]]-I T[[1]])
Tm=(1/2)(T[[2]]+I T[[1]])

elem[t_]:=t[3]T[[3]]+t[2]T[[2]]+t[1]T[[1]]
(ConjugateTranspose[elem[t]]/.Conjugate[t[i_]]->t[i])+elem[t]//MatrixForm
elem[t1]//MatrixForm

Fields

g=MatrixExp[((φ+ϕ)/2)T[[3]]].MatrixExp[θ T[[1]]].MatrixExp[ ((φ-ϕ)/2)T[[3]]]//Simplify;
gi=Inverse[g]//Simplify;

drep[expr_]:=expr/.dp->Dt/.Dt->dp/.dm->Dt/.Dt->dm;
TSimp[expr_]:=Collect[expr//Expand,{dp[f1_]dm[f2_],dpm[f_]},Simplify];
TFSimp[expr_]:=Collect[expr//Expand,{dp[f1_]dm[f2_],dpm[f_]},FullSimplify];

g//MatrixForm

jm=drep[gi.dm[g]]//Simplify;
jp=drep[gi.dp[g]]//Simplify;

J=J0 T[[3]]+J1 Tp+J2 Tm;
Js={J0,J1,J2};
Jc=Jc0 T[[3]]+Jc1 Tp+Jc2 Tm;
Jcs={Jc0,Jc1,Jc2};

Basic Operators

R[X_]:=-c(Tr[X.Tm]Tp-Tr[X.Tp]Tm)
R2[X_]:=c(Tr[X.Tm]Tp-Tr[X.Tp]Tm)

com[R[elem[t1]],R[elem[t2]]]-R[com[elem[t1],R[elem[t2]]]]-R[com[R[elem[t1]],elem[t2]]]+(c^2)com[elem[t1],elem[t2]]//Simplify
com[R2[elem[t1]],R2[elem[t2]]]-R2[com[elem[t1],R2[elem[t2]]]]-R2[com[R2[elem[t1]],elem[t2]]]+(c^2)com[elem[t1],elem[t2]]//Simplify

Rg[X_]:=gi.R[g.X.gi].g

(Subscript[Z, 2]) Automorphism

ω[X_]:=-(1/2)Tr[T[[3]].X]T[[3]]+Tr[X.Tm]Tp+Tr[X.Tp]Tm;
{ω[-I T[[3]]]//MatrixForm,ω[Tp]//MatrixForm,ω[Tm]//MatrixForm}
ω[ω[elem[t1]]]-elem[t1]//Simplify//MatrixForm
com[ω[elem[t1]],ω[elem[t2]]]-ω[com[elem[t1],elem[t2]]]//Simplify//MatrixForm
(Simplify[ConjugateTranspose[ω[elem[t]]]]/.Conjugate[t[i_]]->t[i])+ω[elem[t]]//MatrixForm//Simplify
P0[X_]:=(1/2)(X+ω[X]);
P1[X_]:=(1/2)(X-ω[X]);

J0p=P0[jp]//Simplify;
J0m=P0[jm]//Simplify;
J1p=P1[jp]//Simplify;
J1m=P1[jm]//Simplify;

Models Limits

(*Modelηη={ξp->(1/2)(E^((2 I a b π)/n))((((E^(n (α+β)))-1)(E^(-a β))+((E^(n (α-β)))-1)(E^(a β)))/(((E^(n (α+β)))-1)((E^(n (α-β)))-1)))/.a->1/.b->0,γp->-(1/c)((((E^(n (α+β)))-1)(E^(-a β))-((E^(n (α-β)))-1)(E^(a β)))/(((E^(n (α+β)))-1)(E^(-a β))+((E^(n (α-β)))-1)(E^(a β))))/.a->1,τp->(1/2)(((E^(2 n α))-1)/(((E^(n (α-β)))-1) ((E^(n (α+β)))-1))),χp->(1/c)((((E^(n (α-β)))-1) ((E^(n (α+β)))-1))/((E^(2 n α))-1)),ψp->-(1/c)(E^(n (α-β)))(((E^(2 n β))-1)/((E^(2 n α))-1)),ξm->-(1/2)(E^((2 I a b π)/n))((((E^(n(α+β)))-1)(E^(-(n-a) β))+((E^(n (α-β)))-1)(E^((n-a) β)))/(((E^(n (α+β)))-1)((E^(n (α-β)))-1)))/.a->1/.b->0,γm->(1/c)((((E^(n (α+β)))-1)(E^(-(n-a) β))-((E^(n (α-β)))-1)(E^((n-a) β)))/(((E^(n (α+β)))-1)(E^(-(n-a) β))+((E^(n (α-β)))-1)(E^((n-a)β))))/.a->1,τm->-(1/2)(E^(-n α))(((E^(2 n α))-1)/(((E^(n (α-β)))-1) ((E^(n (α+β)))-1))),χm->-(1/c)((((E^(n (α-β)))-1) ((E^(n (α+β)))-1))/((E^(2 n α))-1)),ψm->(1/c)(E^(n (α-β)))(((E^(2 n β))-1)/((E^(2 n α))-1)),k->(h/(χ(χ+1))),λ->(E^(2α)),χ->(E^(2β))}/.n->2/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;*)
Modelηη={ξp->(((-1+λ) (Sqrt[χ]) (1+χ))/(2 (λ-χ) (-1+λ χ))),γp->-(((1+λ) (-1+χ))/(c (-1+λ) (1+χ))),τp->(((-1+(λ^2)) χ)/(2 (λ-χ) (-1+λ χ))),χp->(((λ-χ) (-1+λ χ))/(c (-1+(λ^2)) χ)),ψp->-((λ-λ (χ^2))/(c χ-c (λ^2) χ)),ξm->(((-1+λ) (Sqrt[χ]) (1+χ))/(2 (-λ+χ) (-1+λ χ))),γm->(((1+λ) (-1+χ))/(c (-1+λ) (1+χ))),τm->(((-1+(λ^2)) χ)/(2 λ (-λ+χ) (-1+λ χ))),χm->(((-λ+χ) (-1+λ χ))/(c (-1+(λ^2)) χ)),ψm->((λ-λ (χ^2))/(c χ-c (λ^2) χ)),k->(h/(χ+(χ^2)))}//TrigToExp//Simplify;

General Operators

(**************************************************)
(**************** Basic Ops A,B,C,D ****************)
(**************************************************)

Ap[X_]:=X+χp R2[X]+ψp Rg[X]//Simplify
Bp[X_]:=X+γp Rg[X]//Simplify
Am[X_]:=X+χm R2[X]+ψm Rg[X]//Simplify
Bm[X_]:=X+γm Rg[X]//Simplify

Apt[X_]:=X-χp R2[X]-ψp Rg[X]//Simplify
Bpt[X_]:=X-γp Rg[X]//Simplify

Api[X_]:=Flatten[J/.Solve[Ap[J]==X,Js],1]//Simplify
Ami[X_]:=Flatten[J/.Solve[Am[J]==X,Js],1]//Simplify
Bpi[X_]:=Flatten[J/.Solve[Bp[J]==X,Js],1]//Simplify
Bmi[X_]:=Flatten[J/.Solve[Bm[J]==X,Js],1]//Simplify

Apit[X_]:=Flatten[J/.Solve[Apt[J]==X,Js],1]//Simplify
Bpit[X_]:=Flatten[J/.Solve[Bpt[J]==X,Js],1]//Simplify

(**************************************************)
(**************** Secondary Ops M,N,O ****************)
(**************************************************)

Mp[X_]:=P0[Bpi[P0[X]]]//Simplify
Mm[X_]:=P0[Bmi[P0[X]]]//Simplify
Mtp[X_]:=P0[Bpi[P1[X]]]//Simplify
Mtm[X_]:=P0[Bmi[P1[X]]]//Simplify
Np[X_]:=P1[Api[P1[X]]]//Simplify
Nm[X_]:=P1[Ami[P1[X]]]//Simplify
Ntp[X_]:=P1[Api[P0[X]]] //Simplify
Ntm[X_]:=P1[Ami[P0[X]]]//Simplify

O0pi[X_]:=P1[X]+P0[Bpi[Ap[P0[X]]]]//Simplify
O0mi[X_]:=P1[X]+P0[Bmi[Am[P0[X]]]]//Simplify
O1pi[X_]:=P0[X]+P1[Api[Bp[P1[X]]]]//Simplify
O1mi[X_]:=P0[X]+P1[Ami[Bm[P1[X]]]]//Simplify

O0p[X_]:=Flatten[Jc/.Solve[O0pi[Jc]==X,Jcs],1]//Simplify
O0m[X_]:=Flatten[Jc/.Solve[O0mi[Jc]==X,Jcs],1]//Simplify
O1p[X_]:=Flatten[Jc/.Solve[O1pi[Jc]==X,Jcs],1]//Simplify
O1m[X_]:=Flatten[Jc/.Solve[O1mi[Jc]==X,Jcs],1]//Simplify

Mpt[X_]:=P0[Bpit[P0[X]]]//Simplify
Mtpt[X_]:=P1[Bpit[P0[X]]]//Simplify
Npt[X_]:=P1[Apit[P1[X]]]//Simplify
Ntpt[X_]:=P0[Apit[P1[X]]] //Simplify

O0pit[X_]:=P1[X]+P0[Apt[Bpit[P0[X]]]]//Simplify
O1pit[X_]:=P0[X]+P1[Bpt[Apit[P1[X]]]]//Simplify

O0pt[X_]:=Flatten[Jc/.Solve[O0pit[Jc]==X,Jcs],1]//Simplify
O1pt[X_]:=Flatten[Jc/.Solve[O1pit[Jc]==X,Jcs],1]//Simplify

(**************************************************)
(***************** Generalised Ops *****************)
(**************************************************)

GMp[X_]:=(1/(τp)) O0p[Mp[X]]//Simplify
GMm[X_]:=(1/(τm)) O0m[Mm[X]]//Simplify
GMtp[X_]:=(1/(τp)) O0p[Mtp[X]]//Simplify
GMtm[X_]:=(1/(τm))O0m[Mtm[X]]//Simplify
GNp[X_]:=(1/(ξp)) O1p[Np[X]]//Simplify
GNm[X_]:=(1/(ξm)) O1m[Nm[X]]//Simplify
GNtp[X_]:=(1/(ξp)) O1p[Ntp[X]]//Simplify
GNtm[X_]:=(1/(ξm)) O1m[Ntm[X]]//Simplify

GMpt[X_]:=(1/(τp)) Mpt[O0pt[X]]//Simplify
GMtpt[X_]:=(1/(τp)) Mtpt[O0pt[X]]//Simplify
GNpt[X_]:=(1/(ξp)) Npt[O1pt[X]]//Simplify
GNtpt[X_]:=(1/(ξp))Ntpt[O1pt[X]]//Simplify

(**************************************************)
(******************* Action Ops D *******************)
(**************************************************)

Dηη00[X_]:=(χ+1)(GMm[X]-λ GMpt[X])//Simplify
Dηη01[X_]:=(χ+1)GMtm[X]-(Sqrt[χ])(λ+1)GNtpt[X]//Simplify
Dηη10[X_]:=(Sqrt[χ])(λ+1)GNtm[X]-λ(χ+1)GMtpt[X]//Simplify
Dηη11[X_]:=(Sqrt[χ])(λ+1)(GNm[X]-GNpt[X])//Simplify

Lax Connection

Laxηp[J0p_,J1p_]:=(1/2)(1+(2/((E^(2α))(z^2)-1)))(GMp[J0p]+GMtp[J1p])+(1/(2c))R2[GMp[J0p]+GMtp[J1p]]+(z/((E^(2α))(z^2)-1))(GNtp[J0p]+GNp[J1p])/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;
Laxηm[J0m_,J1m_]:=((E^(-2α))/2)(1+(2/((E^(-2α))(z^2)-1)))(GMm[J0m]+GMtm[J1m])+((E^(-2α))/(2c))R2[GMm[J0m]+GMtp[J1m]]+(E^(-2α))(z/((E^(-2α))(z^2)-1))(GNtm[J0m]+GNm[J1m])/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["Laxesηη.mx"],<<Laxesηη.mx,
Laxηηp=Laxηp[J0p,J1p]//.Modelηη//FullSimplify;
Laxηηm=Laxηm[J0m,J1m]//.Modelηη//FullSimplify;
DumpSave["Laxesηη.mx",{Laxηηp,Laxηηm}];]
Laxηηp
Laxηηm

Lagrangian

$Assumptions={α,β}∈Reals;
SetAttributes[{h,χ,λ},Constant]

Bulk Lagrangian

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["Lagηη.mx"],<<Lagηη.mx,
Lηη=-2k Tr[J0p.Dηη00[J0m]+J0p.Dηη01[J1m]+J1p.Dηη10[J0m]+J1p.Dηη11[J1m]]//.Modelηη//TrigToExp//TSimp;
DumpSave["Lagηη.mx",{Lηη}];]
Lηη

Variation of the Wess-Zumino term

(*No Wess-Zumino term*)

Equations of Motion

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["EOMηη.mx"],<<EOMηη.mx,
Eηηφ=(Dt[D[Lηη,dm[φ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lηη,dp[φ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)//TSimp;
Eηηϕ=(Dt[D[Lηη,dm[ϕ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lηη,dp[ϕ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)//TSimp;
Eηηθ=(Dt[D[Lηη,dm[θ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lηη,dp[θ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lηη,θ]/.dm'[θ]->0/.dp'[θ]->0)//TSimp;
DumpSave["EOMηη.mx",{Eηηφ,Eηηϕ,Eηηθ}];]
Eηηφ
Eηηϕ
Eηηθ

eomlistηη=-Inverse[{{Coefficient[Eηηφ,dpm[φ]],Coefficient[Eηηφ,dpm[ϕ]],Coefficient[Eηηφ,dpm[θ]]},{Coefficient[Eηηϕ,dpm[φ]],Coefficient[Eηηϕ,dpm[ϕ]],Coefficient[Eηηϕ,dpm[θ]]},{Coefficient[Eηηθ,dpm[φ]],Coefficient[Eηηθ,dpm[ϕ]],Coefficient[Eηηθ,dpm[θ]]}}].{Eηηφ-Sum[Coefficient[Eηηφ,r]r,{r,{dpm[φ],dpm[ϕ],dpm[θ]}}],Eηηϕ-Sum[Coefficient[Eηηϕ,r]r,{r,{dpm[φ],dpm[ϕ],dpm[θ]}}],Eηηθ-Sum[Coefficient[Eηηθ,r]r,{r,{dpm[φ],dpm[ϕ],dpm[θ]}}]}//TSimp

Flatness of the Lax Connection

SetAttributes[z,Constant]

LaxFlatηη=(Dt[Laxηηm]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(Dt[Laxηηp]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+com[Laxηηp,Laxηηm]/.{dpm[φ]->eomlistηη[[1]],dpm[ϕ]->eomlistηη[[2]],dpm[θ]->eomlistηη[[3]]}

Coefficient[LaxFlatηη,dm[φ] dp[φ]]//Simplify
Coefficient[LaxFlatηη,dm[φ] dp[ϕ]]//Simplify
Coefficient[LaxFlatηη,dm[φ] dp[θ]]//Simplify
Coefficient[LaxFlatηη,dm[ϕ] dp[φ]]//Simplify
Coefficient[LaxFlatηη,dm[ϕ] dp[ϕ]]//Simplify
Coefficient[LaxFlatηη,dm[ϕ] dp[θ]]//Simplify
Coefficient[LaxFlatηη,dm[θ] dp[φ]]//Simplify
Coefficient[LaxFlatηη,dm[θ] dp[ϕ]]//Simplify
Coefficient[LaxFlatηη,dm[θ] dp[θ]]//Simplify

Metric

n=3;
coord={φ,ϕ,θ};

GBmetric=Table[Coefficient[Lηη,dm[i] dp[j]],{i,coord},{j,coord}]//Simplify;
metric=(1/2)(GBmetric+Transpose[GBmetric])//FullSimplify;
Bfield=(1/2)(GBmetric-Transpose[GBmetric])//FullSimplify;
metric//MatrixForm
Bfield//MatrixForm

inversemetric=Simplify[Inverse[metric]]//Simplify;
affine=Simplify[Table[(1/2)*Sum[(inversemetric[[i,s]])*
(D[metric[[s,j]],coord[[k]] ]+
D[metric[[s,k]],coord[[j]] ]-D[metric[[j,k]],coord[[s]] ]),{s,1,n}],
{i,1,n},{j,1,n},{k,1,n}] ]//Simplify;
riemann=Simplify[Table[
D[affine[[i,j,l]],coord[[k]] ]-D[affine[[i,j,k]],coord[[l]] ]+
Sum[affine[[s,j,l]] affine[[i,k,s]]-affine[[s,j,k]] affine[[i,l,s]],
{s,1,n}],
{i,1,n},{j,1,n},{k,1,n},{l,1,n}] ]//Simplify;
ricci=Simplify[Table[Sum[riemann[[i,j,i,l]],{i,1,n}],{j,1,n},{l,1,n}] ]//Simplify;

scalar=Simplify[Sum[inversemetric[[i,j]]ricci[[i,j]],{i,1,n},{j,1,n}] ]//Simplify;
scalar