Algebra

com[X_,Y_]:=X.Y-Y.X;

Generators

T={I PauliMatrix[1], I PauliMatrix[2],I PauliMatrix[3]}

Tp=(1/2)(T[[2]]-I T[[1]])
Tm=(1/2)(T[[2]]+I T[[1]])

elem[t_]:=t[3]T[[3]]+t[2]T[[2]]+t[1]T[[1]]
(ConjugateTranspose[elem[t]]/.Conjugate[t[i_]]->t[i])+elem[t]//MatrixForm
elem[t1]//MatrixForm

Fields

g=MatrixExp[((φ+ϕ)/2)T[[3]]].MatrixExp[θ T[[1]]].MatrixExp[((φ-ϕ)/2)T[[3]]]//Simplify;

gi=Inverse[g]//Simplify;
drep[expr_]:=expr/.dp->Dt/.Dt->dp/.dm->Dt/.Dt->dm;
TSimp[expr_]:=Collect[expr//Expand,{dp[f1_]dm[f2_],dpm[f_]},Simplify];
TFSimp[expr_]:=Collect[expr//Expand,{dp[f1_]dm[f2_],dpm[f_]},FullSimplify];

g//MatrixForm

jm=drep[gi.dm[g]]//Simplify;
jp=drep[gi.dp[g]]//Simplify;

J=J0 T[[3]]+J1 Tp+J2 Tm;
Js={J0,J1,J2};
Jc=Jc0 T[[3]]+Jc1 Tp+Jc2 Tm;
Jcs={Jc0,Jc1,Jc2};

Basic Operators

R2[X_]:=c(Tr[X.Tm]Tp-Tr[X.Tp]Tm)

com[R2[elem[t1]],R2[elem[t2]]]-R2[com[elem[t1],R2[elem[t2]]]]-R2[com[R2[elem[t1]],elem[t2]]]+(c^2)com[elem[t1],elem[t2]]//Simplify

Adg[X_]:=g.X.gi
Adgi[X_]:=gi.X.g

(Subscript[Z, 2]) Automorphism

ω[X_]:=-(1/2)Tr[T[[3]].X]T[[3]]+Tr[X.Tm]Tp+Tr[X.Tp]Tm;
{ω[-I T[[3]]]//MatrixForm,ω[Tp]//MatrixForm,ω[Tm]//MatrixForm}
ω[ω[elem[t1]]]-elem[t1]//Simplify//MatrixForm
com[ω[elem[t1]],ω[elem[t2]]]-ω[com[elem[t1],elem[t2]]]//Simplify//MatrixForm
(Simplify[ConjugateTranspose[ω[elem[t]]]]/.Conjugate[t[i_]]->t[i])+ω[elem[t]]//MatrixForm//Simplify
P0[X_]:=(1/2)(X+ω[X]);
P1[X_]:=(1/2)(X-ω[X]);

J0p=P0[jp]//Simplify;
J0m=P0[jm]//Simplify;
J1p=P1[jp]//Simplify;
J1m=P1[jm]//Simplify;

Models Limits

Modelηλ={ξp->((E^(a β+((2 I a b π)/n)))/((E^(n (α+β)))-1))/.a->1/.b->0,γp->-(E^(-2 a β))(((E^(n (α+β)))-1)/((E^(n (α-β)))-1))/.a->1,τp->(1/2)(((E^(n (α+β)))+1)/((E^(n (α+β)))-1)),χp->(1/c)(((E^(n (α+β)))-1)/((E^(n (α+β)))+1)),ψp->-((((E^(n (α+β)))-1)((E^(n (α-β)))+1))/(((E^(n (α+β)))+1)((E^(n (α-β)))-1))),ξm->-((E^(-(n-a)β+((2 I a b π)/n)))/((E^(n (α-β)))-1))/.a->1/.b->0,γm->-(E^(2(n-a) β))(((E^(n (α-β)))-1)/((E^(n (α+β)))-1))/.a->1,τm->-(1/2)(E^(-n α))(((E^(n (α-β)))+1)/((E^(n (α-β)))-1)),χm->-(1/c)(((E^(n (α-β)))-1)/((E^(n (α-β)))+1)),ψm->-((((E^(n (α-β)))-1)((E^(n (α+β)))+1))/(((E^(n (α-β)))+1)((E^(n (α+β)))-1))),k->(h/(2c λ χ((χ^2)-1))),λ->(E^(2α)),χ->(E^(2β))}/.n->2/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;

General Operators

(**************************************************)
(**************** Basic Ops A,B,C,D ****************)
(**************************************************)

Ap[X_]:=X+χp (R2[X]-Adgi[R2[X]])+ψp Adgi[X]//Simplify
Bp[X_]:=X+γp Adgi[X]//Simplify
Am[X_]:=X+χm (R2[X]-Adgi[R2[X]])+ψm Adgi[X]//Simplify
Bm[X_]:=X+γm Adgi[X]//Simplify

Apt[X_]:=X-χp (R2[X]-R2[Adg[X]])+ψp Adg[X]//Simplify
Bpt[X_]:=X+γp Adg[X]//Simplify

Api[X_]:=Flatten[J/.Solve[Ap[J]==X,Js],1]//Simplify
Ami[X_]:=Flatten[J/.Solve[Am[J]==X,Js],1]//Simplify
Bpi[X_]:=Flatten[J/.Solve[Bp[J]==X,Js],1]//Simplify
Bmi[X_]:=Flatten[J/.Solve[Bm[J]==X,Js],1]//Simplify

Apit[X_]:=Flatten[J/.Solve[Apt[J]==X,Js],1]//Simplify
Bpit[X_]:=Flatten[J/.Solve[Bpt[J]==X,Js],1]//Simplify

(**************************************************)
(**************** Secondary Ops M,N,O ****************)
(**************************************************)

Mp[X_]:=P0[Bpi[P0[X]]]//Simplify
Mm[X_]:=P0[Bmi[P0[X]]]//Simplify
Mtp[X_]:=P0[Bpi[P1[X]]]//Simplify
Mtm[X_]:=P0[Bmi[P1[X]]]//Simplify
Np[X_]:=P1[Api[P1[X]]]//Simplify
Nm[X_]:=P1[Ami[P1[X]]]//Simplify
Ntp[X_]:=P1[Api[P0[X]]] //Simplify
Ntm[X_]:=P1[Ami[P0[X]]]//Simplify

O0pi[X_]:=P1[X]+P0[Bpi[Ap[P0[X]]]]//Simplify
O0mi[X_]:=P1[X]+P0[Bmi[Am[P0[X]]]]//Simplify
O1pi[X_]:=P0[X]+P1[Api[Bp[P1[X]]]]//Simplify
O1mi[X_]:=P0[X]+P1[Ami[Bm[P1[X]]]]//Simplify

O0p[X_]:=Flatten[Jc/.Solve[O0pi[Jc]==X,Jcs],1]//Simplify
O0m[X_]:=Flatten[Jc/.Solve[O0mi[Jc]==X,Jcs],1]//Simplify
O1p[X_]:=Flatten[Jc/.Solve[O1pi[Jc]==X,Jcs],1]//Simplify
O1m[X_]:=Flatten[Jc/.Solve[O1mi[Jc]==X,Jcs],1]//Simplify

Mpt[X_]:=P0[Bpit[P0[X]]]//Simplify
Mtpt[X_]:=P1[Bpit[P0[X]]]//Simplify
Npt[X_]:=P1[Apit[P1[X]]]//Simplify
Ntpt[X_]:=P0[Apit[P1[X]]] //Simplify

O0pit[X_]:=P1[X]+P0[Apt[Bpit[P0[X]]]]//Simplify
O1pit[X_]:=P0[X]+P1[Bpt[Apit[P1[X]]]]//Simplify

O0pt[X_]:=Flatten[Jc/.Solve[O0pit[Jc]==X,Jcs],1]//Simplify
O1pt[X_]:=Flatten[Jc/.Solve[O1pit[Jc]==X,Jcs],1]//Simplify

(**************************************************)
(***************** Generalised Ops *****************)
(**************************************************)

GMp[X_]:=(1/(τp)) O0p[Mp[X]]//Simplify
GMm[X_]:=(1/(τm)) O0m[Mm[X]]//Simplify
GMtp[X_]:=(1/(τp)) O0p[Mtp[X]]//Simplify
GMtm[X_]:=(1/(τm))O0m[Mtm[X]]//Simplify
GNp[X_]:=(1/(ξp)) O1p[Np[X]]//Simplify
GNm[X_]:=(1/(ξm)) O1m[Nm[X]]//Simplify
GNtp[X_]:=(1/(ξp)) O1p[Ntp[X]]//Simplify
GNtm[X_]:=(1/(ξm)) O1m[Ntm[X]]//Simplify
GEp[X_]:=(rp/(τp))O0p[Mp[Ep[X]]]//Simplify
GEm[X_]:=(rm/(τm)) O0m[Mm[Em[X]]]//Simplify
GFp[X_]:=(rp/(ξp)) O1p[Ntp[Fp[X]]]//Simplify
GFm[X_]:=(rm/(ξm))O1m[Ntm[Fm[X]]]//Simplify

GMpt[X_]:=(1/(τp)) Mpt[O0pt[X]]//Simplify
GMtpt[X_]:=(1/(τp)) Mtpt[O0pt[X]]//Simplify
GNpt[X_]:=(1/(ξp)) Npt[O1pt[X]]//Simplify
GNtpt[X_]:=(1/(ξp))Ntpt[O1pt[X]]//Simplify
GEpt[X_]:=(rp/(τp)) Ept[Mpt[O0pt[X]]]//Simplify
GFpt[X_]:=(rp/(ξp))Fpt[Ntpt[O1pt[X]]]//Simplify

(**************************************************)
(******************* Action Ops D *******************)
(**************************************************)

Dηλ00[X_]:=(λ χ-1)(c(λ+χ)GMm[X]-(λ-χ)R2[GMm[X]])+λ(λ-χ)(c(λ χ+1)GMpt[X]-(λ χ-1)GMpt[R2[X]]) //Simplify
Dηλ01[X_]:=(λ χ-1)(c(λ+χ)GMtm[X]-(λ-χ)R2[GMtm[X]])+2c λ(Sqrt[χ])(λ-χ)GNtpt[X]//Simplify
Dηλ10[X_]:=λ(2c(Sqrt[χ])(λ χ-1)GNtm[X]+(λ-χ)(c(λ χ+1)GMtpt[X]-(λ χ-1)GMtpt[R2[X]]))//Simplify
Dηλ11[X_]:= 2c λ(Sqrt[χ])((λ χ-1)GNm[X]+(λ-χ)GNpt[X])//Simplify

Lax Connection

Laxηp[J0p_,J1p_]:=(1/2)(1+(2/((E^(2α))(z^2)-1)))(GMp[J0p]+GMtp[J1p])+(1/(2c))R2[GMp[J0p]+GMtp[J1p]]+(z/((E^(2α))(z^2)-1))(GNtp[J0p]+GNp[J1p])/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;
Laxηm[J0m_,J1m_]:=((E^(-2α))/2)(1+(2/((E^(-2α))(z^2)-1)))(GMm[J0m]+GMtm[J1m])+((E^(-2α))/(2c))R2[GMm[J0m]+GMtp[J1m]]+(E^(-2α))(z/((E^(-2α))(z^2)-1))(GNtm[J0m]+GNm[J1m])/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["Laxesηλ.mx"],<<Laxesηλ.mx,
Laxηλp=Laxηp[J0p,J1p]//.Modelηλ//Simplify;
Laxηλm=Laxηm[J0m,J1m]//.Modelηλ//Simplify;
DumpSave["Laxesηλ.mx",{Laxηλp,Laxηλm}];]
Laxηλp
Laxηλm

Lagrangian

$Assumptions={α,β}∈Reals;
SetAttributes[{h,χ,λ},Constant]

Bulk Lagrangian

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["Lagηλ.mx"],<<Lagηλ.mx,
Lηλ=-2k Tr[J0p.Dηλ00[J0m]+J0p.Dηλ01[J1m]+J1p.Dηλ10[J0m]+J1p.Dηλ11[J1m]]//.Modelηλ//TrigToExp//TSimp;
DumpSave["Lagηλ.mx",{Lηλ}];]
Lηλ

Variation of the Wess-Zumino term

q=6;
VWZηλ[X_]:=-2q((h(λ χ-1)(λ (χ^(-1))-1))/(6((χ^2)-1)))Tr[P0[gi.D[g,X]].((Dt[J0p]/.dp'[X]->((dpm[X])/(Dt[X]))/.Dt->dm)-(Dt[J0m]/.dm'[X]->((dpm[X])/(Dt[X]))/.Dt->dp))+P1[gi.D[g,X]].((Dt[J1p]/.dp'[X]->((dpm[X])/(Dt[X]))/.Dt->dm)-(Dt[J1m]/.dm'[X]->((dpm[X])/(Dt[X]))/.Dt->dp))];

VWZVφ=VWZηλ[φ]//TFSimp
VWZVϕ=VWZηλ[ϕ]//TFSimp
VWZVθ=VWZηλ[θ]//TFSimp

Equations of Motion

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["EOMηλ.mx"],<<EOMηλ.mx,
Eηλφ=(Dt[D[Lηλ,dm[φ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lηλ,dp[φ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lηλ,φ]/.dm'[φ]->0/.dp'[φ]->0)+VWZVφ//TSimp;
Eηλϕ=(Dt[D[Lηλ,dm[ϕ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lηλ,dp[ϕ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lηλ,ϕ]/.dm'[ϕ]->0/.dp'[ϕ]->0)+VWZVϕ//TSimp;
Eηλθ=(Dt[D[Lηλ,dm[θ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lηλ,dp[θ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lηλ,θ]/.dm'[θ]->0/.dp'[θ]->0)+VWZVθ//TSimp;
DumpSave["EOMηλ.mx",{Eηλφ,Eηλϕ,Eηλθ}];]
Eηλφ
Eηλϕ
Eηλθ

eomlistηλ=-Inverse[{{Coefficient[Eηλφ,dpm[φ]],Coefficient[Eηλφ,dpm[ϕ]],Coefficient[Eηλφ,dpm[θ]]},{Coefficient[Eηλϕ,dpm[φ]],Coefficient[Eηλϕ,dpm[ϕ]],Coefficient[Eηλϕ,dpm[θ]]},{Coefficient[Eηλθ,dpm[φ]],Coefficient[Eηλθ,dpm[ϕ]],Coefficient[Eηλθ,dpm[θ]]}}].{Eηλφ-Sum[Coefficient[Eηλφ,r]r,{r,{dpm[φ],dpm[ϕ],dpm[θ]}}],Eηλϕ-Sum[Coefficient[Eηλϕ,r]r,{r,{dpm[φ],dpm[ϕ],dpm[θ]}}],Eηλθ-Sum[Coefficient[Eηλθ,r]r,{r,{dpm[φ],dpm[ϕ],dpm[θ]}}]}//TSimp

Flatness of the Lax Connection

SetAttributes[z,Constant]

LaxFlatηλ=(Dt[Laxηλm]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(Dt[Laxηλp]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+com[Laxηλp,Laxηλm]/.{dpm[φ]->eomlistηλ[[1]],dpm[ϕ]->eomlistηλ[[2]],dpm[θ]->eomlistηλ[[3]]}

Coefficient[LaxFlatηλ,dm[φ] dp[φ]]//Simplify
Coefficient[LaxFlatηλ,dm[φ] dp[ϕ]]//Simplify
Coefficient[LaxFlatηλ,dm[φ] dp[θ]]//Simplify
Coefficient[LaxFlatηλ,dm[ϕ] dp[φ]]//Simplify
Coefficient[LaxFlatηλ,dm[ϕ] dp[ϕ]]//Simplify
Coefficient[LaxFlatηλ,dm[ϕ] dp[θ]]//Simplify
Coefficient[LaxFlatηλ,dm[θ] dp[φ]]//Simplify
Coefficient[LaxFlatηλ,dm[θ] dp[ϕ]]//Simplify
Coefficient[LaxFlatηλ,dm[θ] dp[θ]]//Simplify

Metric

n=3;
coord={φ,ϕ,θ};

GBmetric=Table[Coefficient[Lηλ,dm[i] dp[j]],{i,coord},{j,coord}]//Simplify;
metric=(1/2)(GBmetric+Transpose[GBmetric])//FullSimplify;
Bfield=(1/2)(GBmetric-Transpose[GBmetric])//FullSimplify;
metric//MatrixForm
Bfield//MatrixForm

inversemetric=Simplify[Inverse[metric]]//Simplify;
affine=Simplify[Table[(1/2)*Sum[(inversemetric[[i,s]])*
(D[metric[[s,j]],coord[[k]] ]+
D[metric[[s,k]],coord[[j]] ]-D[metric[[j,k]],coord[[s]] ]),{s,1,n}],
{i,1,n},{j,1,n},{k,1,n}] ]//Simplify;
riemann=Simplify[Table[
D[affine[[i,j,l]],coord[[k]] ]-D[affine[[i,j,k]],coord[[l]] ]+
Sum[affine[[s,j,l]] affine[[i,k,s]]-affine[[s,j,k]] affine[[i,l,s]],
{s,1,n}],
{i,1,n},{j,1,n},{k,1,n},{l,1,n}] ]//Simplify;
ricci=Simplify[Table[Sum[riemann[[i,j,i,l]],{i,1,n}],{j,1,n},{l,1,n}] ]//Simplify;

scalar=Simplify[Sum[inversemetric[[i,j]]ricci[[i,j]],{i,1,n},{j,1,n}] ]//Simplify;
scalar