Algebra

com[X_,Y_]:=X.Y-Y.X;

Generators

T={I PauliMatrix[1], I PauliMatrix[2],I PauliMatrix[3]}

Tp=(1/2)(T[[2]]-I T[[1]])
Tm=(1/2)(T[[2]]+I T[[1]])

elem[t_]:=t[3]T[[3]]+t[2]T[[2]]+t[1]T[[1]]
(ConjugateTranspose[elem[t]]/.Conjugate[t[i_]]->t[i])+elem[t]//MatrixForm
elem[t1]//MatrixForm

Fields

g=MatrixExp[I φ T[[3]]].MatrixExp[I θ T[[1]]]//Simplify;
g2=MatrixExp[I ϱ T[[3]]]//Simplify;

gi=Inverse[g]//Simplify;
g2i=Inverse[g2]//Simplify;
drep[expr_]:=expr/.dp->Dt/.Dt->dp/.dm->Dt/.Dt->dm;
TSimp[expr_]:=Collect[expr//Expand,{dp[f1_]dm[f2_],dpm[f_]},Simplify];
TFSimp[expr_]:=Collect[expr//Expand,{dp[f1_]dm[f2_],dpm[f_]},FullSimplify];

g//MatrixForm
g2//MatrixForm

jm=drep[gi.dm[g]]//Simplify;
jp=drep[gi.dp[g]]//Simplify;
j2m=drep[g2i.dm[g2]]//Simplify;
j2p=drep[g2i.dp[g2]]//Simplify;

J=J0 T[[3]]+J1 Tp+J2 Tm;
Js={J0,J1,J2};
Jc=Jc0 T[[3]]+Jc1 Tp+Jc2 Tm;
Jcs={Jc0,Jc1,Jc2};

Basic Operators

R[X_]:=-c(Tr[X.Tm]Tp-Tr[X.Tp]Tm)

com[R[elem[t1]],R[elem[t2]]]-R[com[elem[t1],R[elem[t2]]]]-R[com[R[elem[t1]],elem[t2]]]+(c^2)com[elem[t1],elem[t2]]//Simplify

Rg[X_]:=gi.R[g.X.gi].g

Adg2[X_]:=g2.X.g2i
Adg2i[X_]:=g2i.X.g2

(Subscript[Z, 2]) Automorphism

ω[X_]:=-(1/2)Tr[T[[3]].X]T[[3]]+Tr[X.Tm]Tp+Tr[X.Tp]Tm;
{ω[-I T[[3]]]//MatrixForm,ω[Tp]//MatrixForm,ω[Tm]//MatrixForm}
ω[ω[elem[t1]]]-elem[t1]//Simplify//MatrixForm
com[ω[elem[t1]],ω[elem[t2]]]-ω[com[elem[t1],elem[t2]]]//Simplify//MatrixForm
(Simplify[ConjugateTranspose[ω[elem[t]]]]/.Conjugate[t[i_]]->t[i])+ω[elem[t]]//MatrixForm//Simplify
P0[X_]:=(1/2)(X+ω[X]);
P1[X_]:=(1/2)(X-ω[X]);

J0p=P0[jp]//Simplify;
J0m=P0[jm]//Simplify;
J1p=P1[jp]//Simplify;
J1m=P1[jm]//Simplify;

Models Limits

(*Modelλη={ξp->(1/2)(E^((2 I a b π)/n))((((E^(n (α+β)))-1)(E^(-a β))+((E^(n (α-β)))-1)(E^(a β)))/(((E^(n (α+β)))-1)((E^(n (α-β)))-1)))/.a->1/.b->0,ξ0p->(1/2)(E^((2 I a b π)/n))((((E^(n (α+β)))-1)(E^(-a β))+((E^(n (α-β)))-1)(E^(a β)))/(((E^(n (α+β)))-1)((E^(n (α-β)))-1)))/.a->0/.b->0,γp->-(1/c)((((E^(n (α+β)))-1)(E^(-a β))-((E^(n (α-β)))-1)(E^(a β)))/(((E^(n (α+β)))-1)(E^(-a β))+((E^(n (α-β)))-1)(E^(a β))))/.a->1,γ0p->-(1/c)((((E^(n (α+β)))-1)(E^(-a β))-((E^(n (α-β)))-1)(E^(a β)))/(((E^(n (α+β)))-1)(E^(-a β))+((E^(n (α-β)))-1)(E^(a β))))/.a->0,τp->(1/2)(((1+(E^(2 n β))-2 (E^(n (β+α)))))/(((E^(n (α+β)))-1)((E^(n (β-α)))-1))),χp->((1+(E^(2 n β))-2 (E^(n (-α+β))))/(1+(E^(2 n β))-2 (E^(n (α+β))))),ψp->(1/c)(((E^(2 n β))-1)/(1+(E^(2 n β))-2 (E^(n (α+β))))),ξm->-(1/2)(E^((2 I a b π)/n))((((E^(n(α+β)))-1)(E^(-(n-a) β))+((E^(n (α-β)))-1)(E^((n-a) β)))/(((E^(n (α+β)))-1)((E^(n (α-β)))-1)))/.a->1/.b->0,ξ0m->-(1/2)(E^((2 I a b π)/n))((((E^(n(α+β)))-1)(E^(-(n-a) β))+((E^(n (α-β)))-1)(E^((n-a) β)))/(((E^(n (α+β)))-1)((E^(n (α-β)))-1)))/.a->0/.b->0,γm->(1/c)((((E^(n (α+β)))-1)(E^(-(n-a) β))-((E^(n (α-β)))-1)(E^((n-a) β)))/(((E^(n (α+β)))-1)(E^(-(n-a) β))+((E^(n (α-β)))-1)(E^((n-a)β))))/.a->1,γ0m->(1/c)((((E^(n (α+β)))-1)(E^(-(n-a) β))-((E^(n (α-β)))-1)(E^((n-a) β)))/(((E^(n (α+β)))-1)(E^(-(n-a) β))+((E^(n (α-β)))-1)(E^((n-a)β))))/.a->0,τm->(1/2)(((1+(E^(2 n β))-2 (E^(n (β-α)))))/(((E^(n (α+β)))-1)((E^(n (β-α)))-1))),χm->((1+(E^(2 n β))-2 (E^(n (α+β))))/(1+(E^(2n β))-2 (E^(n (-α+β))))),ψm->(1/c)(((E^(2 n β))-1)/(1+(E^(2n β))-2 (E^(n (-α+β))))),k->(h/(χ(χ+1))),α->(1/2)Log[λ],β->(1/2)Log[χ],n->2}//TrigToExp//Simplify;*)
Modelλη={ξp->(((-1+λ) (Sqrt[χ]) (1+χ))/(2 (λ-χ) (-1+λ χ))),ξ0p->((λ-2 χ+λ (χ^2))/(2 (λ-χ) (-1+λ χ))),γp->-(((1+λ) (-1+χ))/(c (-1+λ) (1+χ))),γ0p->((λ-λ (χ^2))/(c λ-2 c χ+c λ (χ^2))),τp->((λ (-1+2 λ χ-(χ^2)))/(2 (λ-χ) (-1+λ χ))),χp->((λ-2 χ+λ (χ^2))/(λ-2 (λ^2) χ+λ (χ^2))),ψp->((-1+(χ^2))/(c (1-2 λ χ+(χ^2)))),ξm->(((-1+λ) (Sqrt[χ]) (1+χ))/(2 (-λ+χ) (-1+λ χ))),ξ0m->((1-2 λ χ+(χ^2))/(2 (λ-χ) (-1+λ χ))),γm->(((1+λ) (-1+χ))/(c (-1+λ) (1+χ))),γ0m->((1-(χ^2))/(c-2 c λ χ+c (χ^2))),τm->((2 χ-λ (1+(χ^2)))/(2 (λ-χ) (-1+λ χ))),χm->((λ (1-2 λ χ+(χ^2)))/(λ-2 χ+λ (χ^2))),ψm->((λ (-1+(χ^2)))/(c (λ-2 χ+λ (χ^2)))),k->(h/(χ+(χ^2))),α->(1/2)Log[λ],β->(1/2)Log[χ],n->2}//TrigToExp//Simplify;

General Operators

(**************************************************)
(**************** Basic Ops A,B,C,D ****************)
(**************************************************)

Ap[X_]:=X+χp Adg2i[X]+ψp Rg[X - Adg2i[X]]//Simplify
Bp[X_]:=X+γp Rg[X]//Simplify
Ep[X_]:=X+γ0p Rg[X]//Simplify
Fp[X_]:=X+γ0p ω[Rg[ω[X]]]//Simplify
Am[X_]:=X+χm Adg2i[X]+ψm Rg[X - Adg2i[X]]//Simplify
Bm[X_]:=X+γm Rg[X]//Simplify
Em[X_]:=X+γ0m Rg[X]//Simplify

Apt[X_]:=X+χp Adg2[X]-ψp (Rg[X]-Adg2[Rg[X]])//Simplify
Bpt[X_]:=X-γp Rg[X]//Simplify
Ept[X_]:=X-γ0p Rg[X]//Simplify

Api[X_]:=Flatten[J/.Solve[Ap[J]==X,Js],1]//Simplify
Ami[X_]:=Flatten[J/.Solve[Am[J]==X,Js],1]//Simplify
Bpi[X_]:=Flatten[J/.Solve[Bp[J]==X,Js],1]//Simplify
Bmi[X_]:=Flatten[J/.Solve[Bm[J]==X,Js],1]//Simplify

Apit[X_]:=Flatten[J/.Solve[Apt[J]==X,Js],1]//Simplify
Bpit[X_]:=Flatten[J/.Solve[Bpt[J]==X,Js],1]//Simplify

(**************************************************)
(**************** Secondary Ops M,N,O ****************)
(**************************************************)

Mp[X_]:=P0[Bpi[P0[X]]]//Simplify
Mm[X_]:=P0[Bmi[P0[X]]]//Simplify
Mtp[X_]:=P0[Bpi[P1[X]]]//Simplify
Mtm[X_]:=P0[Bmi[P1[X]]]//Simplify
Np[X_]:=P1[Api[P1[X]]]//Simplify
Nm[X_]:=P1[Ami[P1[X]]]//Simplify
Ntp[X_]:=P1[Api[P0[X]]] //Simplify
Ntm[X_]:=P1[Ami[P0[X]]]//Simplify

Pp[X_]:=P0[Bpi[Ep[P0[X]]]]//Simplify
Pm[X_]:=P0[Bmi[Em[P0[X]]]]//Simplify
Ptp[X_]:=P1[Api[Ep[P0[X]]]] //Simplify
Ptm[X_]:=P1[Ami[Em[P0[X]]]]//Simplify

O0pi[X_]:=P1[X]+P0[Bpi[Ap[P0[X]]]]//Simplify
O0mi[X_]:=P1[X]+P0[Bmi[Am[P0[X]]]]//Simplify
O1pi[X_]:=P0[X]+P1[Api[Bp[P1[X]]]]//Simplify
O1mi[X_]:=P0[X]+P1[Ami[Bm[P1[X]]]]//Simplify

O0p[X_]:=Flatten[Jc/.Solve[O0pi[Jc]==X,Jcs],1]//Simplify
O0m[X_]:=Flatten[Jc/.Solve[O0mi[Jc]==X,Jcs],1]//Simplify
O1p[X_]:=Flatten[Jc/.Solve[O1pi[Jc]==X,Jcs],1]//Simplify
O1m[X_]:=Flatten[Jc/.Solve[O1mi[Jc]==X,Jcs],1]//Simplify

Mpt[X_]:=P0[Bpit[P0[X]]]//Simplify
Mtpt[X_]:=P1[Bpit[P0[X]]]//Simplify
Npt[X_]:=P1[Apit[P1[X]]]//Simplify
Ntpt[X_]:=P0[Apit[P1[X]]] //Simplify

Ppt[X_]:=P0[Ept[Bpit[P0[X]]]]//Simplify
Ptpt[X_]:=P0[Ept[Apit[P1[X]]]] //Simplify

O0pit[X_]:=P1[X]+P0[Apt[Bpit[P0[X]]]]//Simplify
O1pit[X_]:=P0[X]+P1[Bpt[Apit[P1[X]]]]//Simplify

O0pt[X_]:=Flatten[Jc/.Solve[O0pit[Jc]==X,Jcs],1]//Simplify
O1pt[X_]:=Flatten[Jc/.Solve[O1pit[Jc]==X,Jcs],1]//Simplify

(**************************************************)
(***************** Generalised Ops *****************)
(**************************************************)

GMp[X_]:=(1/(τp)) O0p[Mp[X]]//Simplify
GMm[X_]:=(1/(τm)) O0m[Mm[X]]//Simplify
GMtp[X_]:=(1/(τp)) O0p[Mtp[X]]//Simplify
GMtm[X_]:=(1/(τm))O0m[Mtm[X]]//Simplify
GNp[X_]:=(1/(ξp)) O1p[Np[X]]//Simplify
GNm[X_]:=(1/(ξm)) O1m[Nm[X]]//Simplify
GNtp[X_]:=(1/(ξp)) O1p[Ntp[X]]//Simplify
GNtm[X_]:=(1/(ξm)) O1m[Ntm[X]]//Simplify

GEp[X_]:=((ξ0p)/(τp))O0p[Pp[X]]//Simplify
GEm[X_]:=((λ ξ0m)/(τm)) O0m[Pm[X]]//Simplify
GFp[X_]:=((ξ0p)/(ξp)) O1p[Ptp[X]]//Simplify
GFm[X_]:=((λ ξ0m)/(ξm))O1m[Ptm[X]]//Simplify

GMpt[X_]:=(1/(τp)) Mpt[O0pt[X]]//Simplify
GMtpt[X_]:=(1/(τp)) Mtpt[O0pt[X]]//Simplify
GNpt[X_]:=(1/(ξp)) Npt[O1pt[X]]//Simplify
GNtpt[X_]:=(1/(ξp))Ntpt[O1pt[X]]//Simplify
GEpt[X_]:=((ξ0p)/(τp)) Ppt[O0pt[X]]//Simplify
GFpt[X_]:=((ξ0p)/(ξp))Ptpt[O1pt[X]]//Simplify

(**************************************************)
(******************* Action Ops D *******************)
(**************************************************)

Dλη00[X_]:=λ(1+χ)((GMm[X]-Adg2i[GMm[X]])-GMpt[X - Adg2[X]])//Simplify
Dλη01[X_]:=λ(1+χ)(GMtm[X]-Adg2i[GMtm[X]])-(Sqrt[χ])(1+λ)GNtpt[X]//Simplify
Dλη02[X_]:=-λ(1+χ)(X-(GEm[X]-Adg2i[GEm[X]])+GMpt[Adg2[X]])//Simplify
Dλη10[X_]:=(Sqrt[χ])(1+λ)GNtm[X]- λ(1+χ)GMtpt[X - Adg2[X]]//Simplify
Dλη11[X_]:=(Sqrt[χ])(1+λ)(GNm[X]-GNpt[X])//Simplify
Dλη12[X_]:=(Sqrt[χ])(1+λ)GFm[X]-λ(1+χ)GMtpt[Adg2[X]]//Simplify
Dλη20[X_]:=λ(1+χ)(X+Adg2i[GMm[X]]-GEpt[X - Adg2[X]])//Simplify
Dλη21[X_]:=λ(1+χ)Adg2i[GMtm[X]]-(Sqrt[χ])(1+λ)GFpt[X]//Simplify
Dλη22[X_]:=λ(1+χ)(Adg2i[GEm[X]]-GEpt[Adg2[X]])//Simplify

Lax Connection

(*Laxλp[J0p_,J1p_,j2p_]:=-(1/((E^(2α))(z^2)-1))j2p+(1+(1/((E^(2α))(z^2)-1)))(GMp[J0p]+GMtp[J1p]+GEp[j2p])-(1/((E^(2α))(z^2)-1))Adg2i[GMp[J0p]+GMtp[J1p]+GEp[j2p]]+(z/((E^(2α))(z^2)-1))(GNtp[J0p]+GNp[J1p]+GFp[j2p])/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;
Laxλm[J0m_,J1m_,j2m_]:= -(1/((E^(-2α))(z^2)-1))j2m+(1+(1/((E^(-2α))(z^2)-1)))(GMm[J0m]+GMtm[J1m]+GEm[j2m])-(1/((E^(-2α))(z^2)-1))Adg2i[GMm[J0m]+GMtm[J1m]+GEm[j2m]]+(E^(-2α))(z/((E^(-2α))(z^2)-1))(GNtm[J0m]+GNm[J1m]+GFm[j2m])/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;*)
Laxλp[J0p_,J1p_,j2p_]:=-(1/(λ (z^2)-1))j2p+(1+(1/(λ (z^2)-1)))(GMp[J0p]+GMtp[J1p]+GEp[j2p])-(1/(λ (z^2)-1))Adg2i[GMp[J0p]+GMtp[J1p]+GEp[j2p]]+(z/(λ (z^2)-1))(GNtp[J0p]+GNp[J1p]+GFp[j2p]);
Laxλm[J0m_,J1m_,j2m_]:= -(1/((λ^(-1))(z^2)-1))j2m+(1+(1/((λ^(-1))(z^2)-1)))(GMm[J0m]+GMtm[J1m]+GEm[j2m])-(1/((λ^(-1))(z^2)-1))Adg2i[GMm[J0m]+GMtm[J1m]+GEm[j2m]]+(λ^(-1))(z/((λ^(-1))(z^2)-1))(GNtm[J0m]+GNm[J1m]+GFm[j2m]);

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["Laxesλη.mx"],<<Laxesλη.mx,
Laxληp=Laxλp[J0p,J1p,j2p]//.Modelλη//Simplify;
Laxληm=Laxλm[J0m,J1m,j2m]//.Modelλη//Simplify;
DumpSave["Laxesλη.mx",{Laxληp,Laxληm}];]
Laxληp
Laxληm

Lagrangian

$Assumptions={α,β}∈Reals;
SetAttributes[{h,χ,λ,α,β},Constant]

Bulk Lagrangian

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["Lagλη.mx"],<<Lagλη.mx,
Lλη=-2k Tr[J0p.Dλη00[J0m]+J0p.Dλη01[J1m]+J0p.Dλη02[j2m]+J1p.Dλη10[J0m]+J1p.Dλη11[J1m]+J1p.Dλη12[j2m]+j2p.Dλη20[J0m]+j2p.Dλη21[J1m]+j2p.Dλη22[j2m]]//.Modelλη//TrigToExp//TSimp;
DumpSave["Lagλη.mx",{Lλη}];]
Lλη

Variation of the Wess-Zumino term

q=6;
VWZλη[X_]:=2q((h λ)/(3χ))Tr[g2i.D[g2,X].((Dt[j2p]/.dp'[X]->((dpm[X])/(Dt[X]))/.Dt->dm)-(Dt[j2m]/.dm'[X]->((dpm[X])/(Dt[X]))/.Dt->dp))];

VWZVϱ=VWZλη[ϱ]//TSimp

Equations of Motion

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["EOMλη.mx"],<<EOMλη.mx,
Eληφ=(Dt[D[Lλη,dm[φ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lλη,dp[φ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lλη,φ]/.dm'[φ]->0/.dp'[φ]->0)//TSimp;
Eληθ=(Dt[D[Lλη,dm[θ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lλη,dp[θ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lλη,θ]/.dm'[θ]->0/.dp'[θ]->0)//TSimp;
Eληϱ=(Dt[D[Lλη,dm[ϱ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lλη,dp[ϱ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lλη,ϱ]/.dm'[ϱ]->0/.dp'[ϱ]->0)+VWZVϱ//TSimp;
DumpSave["EOMλη.mx",{Eληφ,Eληθ,Eληϱ}];]
Eληφ
Eληθ
Eληϱ

eomlistλη=-Inverse[{{Coefficient[Eληφ,dpm[φ]],Coefficient[Eληφ,dpm[θ]],Coefficient[Eληφ,dpm[ϱ]]},{Coefficient[Eληθ,dpm[φ]],Coefficient[Eληθ,dpm[θ]],Coefficient[Eληθ,dpm[ϱ]]},{Coefficient[Eληϱ,dpm[φ]],Coefficient[Eληϱ,dpm[θ]],Coefficient[Eληϱ,dpm[ϱ]]}}].{Eληφ-Sum[Coefficient[Eληφ,r]r,{r,{dpm[φ],dpm[θ],dpm[ϱ]}}],Eληθ-Sum[Coefficient[Eληθ,r]r,{r,{dpm[φ],dpm[θ],dpm[ϱ]}}],Eληϱ-Sum[Coefficient[Eληϱ,r]r,{r,{dpm[φ],dpm[θ],dpm[ϱ]}}]}//TSimp

Flatness of the Lax Connection

SetAttributes[z,Constant]

LaxFlatλη=(Dt[Laxληm]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(Dt[Laxληp]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+com[Laxληp,Laxληm]/.{dpm[φ]->eomlistλη[[1]],dpm[θ]->eomlistλη[[2]],dpm[ϱ]->eomlistλη[[3]]}

Coefficient[LaxFlatλη,dm[φ] dp[φ]]//Simplify
Coefficient[LaxFlatλη,dm[φ] dp[ϱ]]//Simplify
Coefficient[LaxFlatλη,dm[φ] dp[θ]]//Simplify
Coefficient[LaxFlatλη,dm[ϱ] dp[φ]]//Simplify
Coefficient[LaxFlatλη,dm[ϱ] dp[ϱ]]//Simplify
Coefficient[LaxFlatλη,dm[ϱ] dp[θ]]//Simplify
Coefficient[LaxFlatλη,dm[θ] dp[φ]]//Simplify
Coefficient[LaxFlatλη,dm[θ] dp[ϱ]]//Simplify
Coefficient[LaxFlatλη,dm[θ] dp[θ]]//Simplify

Metric

n=3;
coord={φ,θ,ϱ};

GBmetric=Table[Coefficient[Lλη,dm[i] dp[j]],{i,coord},{j,coord}]//Simplify;
metric=(1/2)(GBmetric+Transpose[GBmetric])//FullSimplify;
Bfield=(1/2)(GBmetric-Transpose[GBmetric])//FullSimplify;
metric//MatrixForm
Bfield//MatrixForm

inversemetric=Simplify[Inverse[metric]]//Simplify;
affine=Simplify[Table[(1/2)*Sum[(inversemetric[[i,s]])*
(D[metric[[s,j]],coord[[k]] ]+
D[metric[[s,k]],coord[[j]] ]-D[metric[[j,k]],coord[[s]] ]),{s,1,n}],
{i,1,n},{j,1,n},{k,1,n}] ]//Simplify;
riemann=Simplify[Table[
D[affine[[i,j,l]],coord[[k]] ]-D[affine[[i,j,k]],coord[[l]] ]+
Sum[affine[[s,j,l]] affine[[i,k,s]]-affine[[s,j,k]] affine[[i,l,s]],
{s,1,n}],
{i,1,n},{j,1,n},{k,1,n},{l,1,n}] ]//Simplify;
ricci=Simplify[Table[Sum[riemann[[i,j,i,l]],{i,1,n}],{j,1,n},{l,1,n}] ]//Simplify;

scalar=Simplify[Sum[inversemetric[[i,j]]ricci[[i,j]],{i,1,n},{j,1,n}] ]//Simplify;
scalar