Algebra

com[X_,Y_]:=X.Y-Y.X;

Generators

T={I PauliMatrix[1], I PauliMatrix[2],I PauliMatrix[3]}

Tp=(1/2)(T[[2]]-I T[[1]])
Tm=(1/2)(T[[2]]+I T[[1]])

elem[t_]:=t[3]T[[3]]+t[2]T[[2]]+t[1]T[[1]]
(ConjugateTranspose[elem[t]]/.Conjugate[t[i_]]->t[i])+elem[t]//MatrixForm
elem[t1]//MatrixForm

Fields

g=MatrixExp[(φ/2)T[[3]]].MatrixExp[θ T[[1]]].MatrixExp[(φ/2)T[[3]]]//Simplify;
g2=MatrixExp[ϱ T[[3]]]//Simplify;

gi=Inverse[g]//Simplify;
g2i=Inverse[g2]//Simplify;
drep[expr_]:=expr/.dp->Dt/.Dt->dp/.dm->Dt/.Dt->dm;
TSimp[expr_]:=Collect[expr//Expand,{dp[f1_]dm[f2_],dpm[f_]},Simplify];
TFSimp[expr_]:=Collect[expr//Expand,{dp[f1_]dm[f2_],dpm[f_]},FullSimplify];

g//MatrixForm
g2//MatrixForm

jm=drep[gi.dm[g]]//Simplify;
jp=drep[gi.dp[g]]//Simplify;
j2m=drep[g2i.dm[g2]]//Simplify;
j2p=drep[g2i.dp[g2]]//Simplify;

J=J0 T[[3]]+J1 Tp+J2 Tm;
Js={J0,J1,J2};
Jc=Jc0 T[[3]]+Jc1 Tp+Jc2 Tm;
Jcs={Jc0,Jc1,Jc2};

Basic Operators

Adg[X_]:=g.X.gi
Adg2[X_]:=g2.X.g2i

Adgi[X_]:=gi.X.g
Adg2i[X_]:=g2i.X.g2

(Subscript[Z, 2]) Automorphism

ω[X_]:=-(1/2)Tr[T[[3]].X]T[[3]]+Tr[X.Tm]Tp+Tr[X.Tp]Tm;
{ω[-I T[[3]]]//MatrixForm,ω[Tp]//MatrixForm,ω[Tm]//MatrixForm}
ω[ω[elem[t1]]]-elem[t1]//Simplify//MatrixForm
com[ω[elem[t1]],ω[elem[t2]]]-ω[com[elem[t1],elem[t2]]]//Simplify//MatrixForm
(Simplify[ConjugateTranspose[ω[elem[t]]]]/.Conjugate[t[i_]]->t[i])+ω[elem[t]]//MatrixForm//Simplify
P0[X_]:=(1/2)(X+ω[X]);
P1[X_]:=(1/2)(X-ω[X]);

J0p=P0[jp]//Simplify;
J0m=P0[jm]//Simplify;
J1p=P1[jp]//Simplify;
J1m=P1[jm]//Simplify;

Models Limits

(*Modelλλ={ξp->((E^(a β+((2 I a b π)/n)))/((E^(n (α+β)))-1))/.a->1/.b->0,ξ0p->((E^(a β+((2 I a b π)/n)))/((E^(n (α+β)))-1))/.a->0/.b->0,γp->-(E^(-2 a β))(((E^(n (α+β)))-1)/((E^(n (α-β)))-1))/.a->1,γ0p->-(E^(-2 a β))(((E^(n (α+β)))-1)/((E^(n (α-β)))-1))/.a->0,τp->-(1/((E^(-n (α+β)))-1)),χp->-(E^(-n (α+β))),ψp->-(((E^(-n (α+β)))-1)/((E^(n (-α+β)))-1)),κp->-(((E^(-n (α+β)))-1)/((E^(-n (-α+β)))-1)),ξm->-((E^(-(n-a)β+((2 I a b π)/n)))/((E^(n (α-β)))-1))/.a->1/.b->0,ξ0m->-((E^(-(n-a)β+((2 I a b π)/n)))/((E^(n (α-β)))-1))/.a->0/.b->0,γm->-(E^(2(n-a) β))(((E^(n (α-β)))-1)/((E^(n (α+β)))-1))/.a->1,γ0m->-(E^(2(n-a) β))(((E^(n (α-β)))-1)/((E^(n (α+β)))-1))/.a->0,τm->-(1/((E^(-n (-α+β)))-1)),χm->-(E^(-n (-α+β))),ψm->-(((E^(-n (-α+β)))-1)/((E^(n (α+β)))-1)),κm->-(((E^(-n (-α+β)))-1)/((E^(-n (α+β)))-1)),k->(h/(χ((χ^2)-1))),n->2,α->(1/2)Log[λ],β->(1/2)Log[χ]}//TrigToExp//Simplify;*)
Modelλλ={ξp->((Sqrt[χ])/(-1+λ χ)),ξ0p->(1/(-1+λ χ)),γp->((-1+λ χ)/(-λ+χ)),γ0p->((χ (-1+λ χ))/(-λ+χ)),τp->1+(1/(-1+λ χ)),χp->-(1/(λ χ)),ψp->((-1+λ χ)/(χ (-λ+χ))),κp->((-1+λ χ)/(λ (λ-χ))),ξm->((Sqrt[χ])/(-λ+χ)),ξ0m->(1/(-λ+χ)),γm->((-λ+χ)/(-1+λ χ)),γ0m->((χ (-λ+χ))/(-1+λ χ)),τm->(χ/(-λ+χ)),χm->-(λ/χ),ψm->((λ-χ)/(χ-λ (χ^2))),κm->((λ (λ-χ))/(-1+λ χ)),k->(h/(χ (-1+(χ^2)))),n->2,α->(1/2)Log[λ],β->(1/2)Log[χ],c->I};

General Operators

(**************************************************)
(**************** Basic Ops A,B,C,D ****************)
(**************************************************)

Ap[X_]:=X+χp Adg2i[X]+ψp Adgi[X]+κp Adgi[Adg2i[X]]//Simplify
Bp[X_]:=X+γp Adgi[X]//Simplify
Ep[X_]:=X+γ0p Adgi[X]//Simplify
Am[X_]:=X+χm Adg2i[X]+ψm Adgi[X]+κm Adgi[Adg2i[X]]//Simplify
Bm[X_]:=X+γm Adgi[X]//Simplify
Em[X_]:=X+γ0m Adgi[X]//Simplify

Apt[X_]:=X+χp Adg2[X]+ψp Adg[X]+κp Adg2[Adg[X]]//Simplify
Bpt[X_]:=X+γp Adg[X]//Simplify
Ept[X_]:=X+γ0p Adg[X]//Simplify

Api[X_]:=Flatten[J/.Solve[Ap[J]==X,Js],1]//Simplify
Ami[X_]:=Flatten[J/.Solve[Am[J]==X,Js],1]//Simplify
Bpi[X_]:=Flatten[J/.Solve[Bp[J]==X,Js],1]//Simplify
Bmi[X_]:=Flatten[J/.Solve[Bm[J]==X,Js],1]//Simplify

Apit[X_]:=Flatten[J/.Solve[Apt[J]==X,Js],1]//Simplify
Bpit[X_]:=Flatten[J/.Solve[Bpt[J]==X,Js],1]//Simplify

(**************************************************)
(**************** Secondary Ops M,N,O ****************)
(**************************************************)

Mp[X_]:=P0[Bpi[P0[X]]]//Simplify
Mm[X_]:=P0[Bmi[P0[X]]]//Simplify
Mtp[X_]:=P0[Bpi[P1[X]]]//Simplify
Mtm[X_]:=P0[Bmi[P1[X]]]//Simplify
Np[X_]:=P1[Api[P1[X]]]//Simplify
Nm[X_]:=P1[Ami[P1[X]]]//Simplify
Ntp[X_]:=P1[Api[P0[X]]] //Simplify
Ntm[X_]:=P1[Ami[P0[X]]]//Simplify

Pp[X_]:=P0[Bpi[Ep[P0[X]]]]//Simplify
Pm[X_]:=P0[Bmi[Em[P0[X]]]]//Simplify
Ptp[X_]:=P1[Api[Ep[P0[X]]]] //Simplify
Ptm[X_]:=P1[Ami[Em[P0[X]]]]//Simplify

O0pi[X_]:=P1[X]+P0[Bpi[Ap[P0[X]]]]//Simplify
O0mi[X_]:=P1[X]+P0[Bmi[Am[P0[X]]]]//Simplify
O1pi[X_]:=P0[X]+P1[Api[Bp[P1[X]]]]//Simplify
O1mi[X_]:=P0[X]+P1[Ami[Bm[P1[X]]]]//Simplify

O0p[X_]:=Flatten[Jc/.Solve[O0pi[Jc]==X,Jcs],1]//Simplify
O0m[X_]:=Flatten[Jc/.Solve[O0mi[Jc]==X,Jcs],1]//Simplify
O1p[X_]:=Flatten[Jc/.Solve[O1pi[Jc]==X,Jcs],1]//Simplify
O1m[X_]:=Flatten[Jc/.Solve[O1mi[Jc]==X,Jcs],1]//Simplify

Mpt[X_]:=P0[Bpit[P0[X]]]//Simplify
Mtpt[X_]:=P1[Bpit[P0[X]]]//Simplify
Npt[X_]:=P1[Apit[P1[X]]]//Simplify
Ntpt[X_]:=P0[Apit[P1[X]]] //Simplify

Ppt[X_]:=P0[Ept[Bpit[P0[X]]]]//Simplify
Ptpt[X_]:=P0[Ept[Apit[P1[X]]]] //Simplify

O0pit[X_]:=P1[X]+P0[Apt[Bpit[P0[X]]]]//Simplify
O1pit[X_]:=P0[X]+P1[Bpt[Apit[P1[X]]]]//Simplify

O0pt[X_]:=Flatten[Jc/.Solve[O0pit[Jc]==X,Jcs],1]//Simplify
O1pt[X_]:=Flatten[Jc/.Solve[O1pit[Jc]==X,Jcs],1]//Simplify

(**************************************************)
(***************** Generalised Ops *****************)
(**************************************************)

GMp[X_]:=(1/(τp)) O0p[Mp[X]]//Simplify
GMm[X_]:=(1/(τm)) O0m[Mm[X]]//Simplify
GMtp[X_]:=(1/(τp)) O0p[Mtp[X]]//Simplify
GMtm[X_]:=(1/(τm))O0m[Mtm[X]]//Simplify
GNp[X_]:=(1/(ξp)) O1p[Np[X]]//Simplify
GNm[X_]:=(1/(ξm)) O1m[Nm[X]]//Simplify
GNtp[X_]:=(1/(ξp)) O1p[Ntp[X]]//Simplify
GNtm[X_]:=(1/(ξm)) O1m[Ntm[X]]//Simplify

GEp[X_]:=((ξ0p)/(τp))O0p[Pp[X]]//Simplify
GEm[X_]:=((λ ξ0m)/(τm)) O0m[Pm[X]]//Simplify
GFp[X_]:=((ξ0p)/(ξp)) O1p[Ptp[X]]//Simplify
GFm[X_]:=((λ ξ0m)/(ξm))O1m[Ptm[X]]//Simplify

GMpt[X_]:=(1/(τp)) Mpt[O0pt[X]]//Simplify
GMtpt[X_]:=(1/(τp)) Mtpt[O0pt[X]]//Simplify
GNpt[X_]:=(1/(ξp)) Npt[O1pt[X]]//Simplify
GNtpt[X_]:=(1/(ξp))Ntpt[O1pt[X]]//Simplify
GEpt[X_]:=((ξ0p)/(τp)) Ppt[O0pt[X]]//Simplify
GFpt[X_]:=((ξ0p)/(ξp))Ptpt[O1pt[X]]//Simplify

(**************************************************)
(******************* Action Ops D *******************)
(**************************************************)

Dλλ00[X_]:=(λ χ-1)(χ GMm[X]-λ Adg2i[GMm[X]])+(λ-χ)GMpt[λ χ X-Adg2[X]]//Simplify
Dλλ01[X_]:=(λ χ-1)(χ GMtm[X]-λ Adg2i[GMtm[X]])+(Sqrt[χ])(λ-χ)GNtpt[X]//Simplify
Dλλ02[X_]:=-λ(λ χ-1)X+(λ χ-1)(χ GEm[X]-λ Adg2i[GEm[X]])-λ((χ^2)-1)GMpt[Adg2[X]]//Simplify
Dλλ10[X_]:=(Sqrt[χ])(λ χ-1)GNtm[X]+(λ-χ)GMtpt[λ χ X-Adg2[X]]//Simplify
Dλλ11[X_]:=(Sqrt[χ])((λ χ-1)GNm[X]+(λ-χ)GNpt[X])//Simplify
Dλλ12[X_]:=(Sqrt[χ])(λ χ-1)GFm[X]-λ((χ^2)-1)GMtpt[Adg2[X]]//Simplify
Dλλ20[X_]:=-(λ-χ)X+λ((χ^2)-1)Adg2i[GMm[X]]+(λ-χ)GEpt[λ χ X-Adg2[X]]//Simplify
Dλλ21[X_]:=λ((χ^2)-1)Adg2i[GMtm[X]]+(Sqrt[χ])(λ-χ)GFpt[X]//Simplify
Dλλ22[X_]:=λ((χ^2)-1)(Adg2i[GEm[X]]-GEpt[Adg2[X]])//Simplify

Lax Connection

(*Laxλp[J0p_,J1p_,j2p_]:=-(1/((E^(2α))(z^2)-1))j2p+(1+(1/((E^(2α))(z^2)-1)))(GMp[J0p]+GMtp[J1p]+GEp[j2p])-(1/((E^(2α))(z^2)-1))Adg2i[GMp[J0p]+GMtp[J1p]+GEp[j2p]]+(z/((E^(2α))(z^2)-1))(GNtp[J0p]+GNp[J1p]+GFp[j2p])/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;
Laxλm[J0m_,J1m_,j2m_]:= -(1/((E^(-2α))(z^2)-1))j2m+(1+(1/((E^(-2α))(z^2)-1)))(GMm[J0m]+GMtm[J1m]+GEm[j2m])-(1/((E^(-2α))(z^2)-1))Adg2i[GMm[J0m]+GMtm[J1m]+GEm[j2m]]+(E^(-2α))(z/((E^(-2α))(z^2)-1))(GNtm[J0m]+GNm[J1m]+GFm[j2m])/.α->(1/2)Log[λ]/.β->(1/2)Log[χ]//TrigToExp//Simplify;*)
Laxλp[J0p_,J1p_,j2p_]:=-(1/(λ (z^2)-1))j2p+(1+(1/(λ (z^2)-1)))(GMp[J0p]+GMtp[J1p]+GEp[j2p])-(1/(λ (z^2)-1))Adg2i[GMp[J0p]+GMtp[J1p]+GEp[j2p]]+(z/(λ (z^2)-1))(GNtp[J0p]+GNp[J1p]+GFp[j2p]);
Laxλm[J0m_,J1m_,j2m_]:= -(1/((λ^(-1))(z^2)-1))j2m+(1+(1/((λ^(-1))(z^2)-1)))(GMm[J0m]+GMtm[J1m]+GEm[j2m])-(1/((λ^(-1))(z^2)-1))Adg2i[GMm[J0m]+GMtm[J1m]+GEm[j2m]]+(λ^(-1))(z/((λ^(-1))(z^2)-1))(GNtm[J0m]+GNm[J1m]+GFm[j2m]);

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["Laxesλλ.mx"],<<Laxesλλ.mx,
Laxλλp=Laxλp[J0p,J1p,j2p]//.Modelλλ//Simplify;
Laxλλm=Laxλm[J0m,J1m,j2m]//.Modelλλ//Simplify;
DumpSave["Laxesλλ.mx",{Laxλλp,Laxλλm}];]
Laxλλp
Laxλλm

Lagrangian

$Assumptions={α,β}∈Reals;
SetAttributes[{h,χ,λ},Constant]

Bulk Lagrangian

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["Lagλλ.mx"],<<Lagλλ.mx,
Lλλ=-2k Tr[J0p.Dλλ00[J0m]+J0p.Dλλ01[J1m]+J0p.Dλλ02[j2m]+J1p.Dλλ10[J0m]+J1p.Dλλ11[J1m]+J1p.Dλλ12[j2m]+j2p.Dλλ20[J0m]+j2p.Dλλ21[J1m]+j2p.Dλλ22[j2m]]//.Modelλλ//TrigToExp//TSimp;
DumpSave["Lagλλ.mx",{Lλλ}];]
Lλλ

Variation of the Wess-Zumino term

q=6;
VWZηλ[X_]:=-2q((h(λ χ-1)(λ (χ^(-1))-1))/(6((χ^2)-1)))Tr[P0[gi.D[g,X]].((Dt[J0p]/.dp'[X]->((dpm[X])/(Dt[X]))/.Dt->dm)-(Dt[J0m]/.dm'[X]->((dpm[X])/(Dt[X]))/.Dt->dp))+P1[gi.D[g,X]].((Dt[J1p]/.dp'[X]->((dpm[X])/(Dt[X]))/.Dt->dm)-(Dt[J1m]/.dm'[X]->((dpm[X])/(Dt[X]))/.Dt->dp))];
VWZλη[X_]:=2q((h λ)/(3χ))Tr[gi.D[g,X].((Dt[j2p]/.dp'[X]->((dpm[X])/(Dt[X]))/.Dt->dm)-(Dt[j2m]/.dm'[X]->((dpm[X])/(Dt[X]))/.Dt->dp))];
VWZλλ[X_]:=VWZηλ[X]+VWZλη[X];

VWZVφ=VWZηλ[φ]//TSimp
VWZVθ=VWZηλ[θ]//TSimp
VWZVϱ=VWZλη[ϱ]//TSimp

Equations of Motion

SetDirectory[NotebookDirectory[]];
If[FileExistsQ["EOMλλ.mx"],<<EOMλλ.mx,
Eλλφ=(Dt[D[Lλλ,dm[φ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lλλ,dp[φ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lλλ,φ]/.dm'[φ]->0/.dp'[φ]->0)+VWZVφ//TSimp;
Eλλθ=(Dt[D[Lλλ,dm[θ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lλλ,dp[θ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lλλ,θ]/.dm'[θ]->0/.dp'[θ]->0)+VWZVθ//TSimp;
Eλλϱ=(Dt[D[Lλλ,dm[ϱ]]]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+(Dt[D[Lλλ,dp[ϱ]]]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(D[Lλλ,ϱ]/.dm'[ϱ]->0/.dp'[ϱ]->0)+VWZVϱ//TSimp;
DumpSave["EOMλλ.mx",{Eλλφ,Eλλθ,Eλλϱ}];]
Eλλφ
Eλλθ
Eλλϱ

eomlistλλ=-Inverse[{{Coefficient[Eλλφ,dpm[φ]],Coefficient[Eλλφ,dpm[θ]],Coefficient[Eλλφ,dpm[ϱ]]},{Coefficient[Eλλθ,dpm[φ]],Coefficient[Eλλθ,dpm[θ]],Coefficient[Eλλθ,dpm[ϱ]]},{Coefficient[Eλλϱ,dpm[φ]],Coefficient[Eλλϱ,dpm[θ]],Coefficient[Eλλϱ,dpm[ϱ]]}}].{Eλλφ-Sum[Coefficient[Eλλφ,r]r,{r,{dpm[φ],dpm[θ],dpm[ϱ]}}],Eλλθ-Sum[Coefficient[Eλλθ,r]r,{r,{dpm[φ],dpm[θ],dpm[ϱ]}}],Eλλϱ-Sum[Coefficient[Eλλϱ,r]r,{r,{dpm[φ],dpm[θ],dpm[ϱ]}}]}//TSimp

Flatness of the Lax Connection

SetAttributes[z,Constant]

LaxFlatλλ=(Dt[Laxλλm]/.dm'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dp)-(Dt[Laxλλp]/.dp'[X_]:>((dpm[X])/(Dt[X]))/.Dt->dm)+com[Laxλλp,Laxλλm]/.{dpm[φ]->eomlistλλ[[1]],dpm[θ]->eomlistλλ[[2]],dpm[ϱ]->eomlistλλ[[3]]}

Coefficient[LaxFlatλλ,dm[φ] dp[φ]]//Simplify
Coefficient[LaxFlatλλ,dm[φ] dp[ϱ]]//Simplify
Coefficient[LaxFlatλλ,dm[φ] dp[θ]]//Simplify
Coefficient[LaxFlatλλ,dm[ϱ] dp[φ]]//Simplify
Coefficient[LaxFlatλλ,dm[ϱ] dp[ϱ]]//Simplify
Coefficient[LaxFlatλλ,dm[ϱ] dp[θ]]//Simplify
Coefficient[LaxFlatλλ,dm[θ] dp[φ]]//Simplify
Coefficient[LaxFlatλλ,dm[θ] dp[ϱ]]//Simplify
Coefficient[LaxFlatλλ,dm[θ] dp[θ]]//Simplify

Metric

n=3;
coord={φ,θ,ϱ};

GBmetric=Table[Coefficient[Lλλ,dm[i] dp[j]],{i,coord},{j,coord}]//Simplify;
metric=(1/2)(GBmetric+Transpose[GBmetric])//FullSimplify;
Bfield=(1/2)(GBmetric-Transpose[GBmetric])//FullSimplify;
metric//MatrixForm
Bfield//MatrixForm

inversemetric=Simplify[Inverse[metric]]//Simplify;
affine=Simplify[Table[(1/2)*Sum[(inversemetric[[i,s]])*
(D[metric[[s,j]],coord[[k]] ]+
D[metric[[s,k]],coord[[j]] ]-D[metric[[j,k]],coord[[s]] ]),{s,1,n}],
{i,1,n},{j,1,n},{k,1,n}] ]//Simplify;
riemann=Simplify[Table[
D[affine[[i,j,l]],coord[[k]] ]-D[affine[[i,j,k]],coord[[l]] ]+
Sum[affine[[s,j,l]] affine[[i,k,s]]-affine[[s,j,k]] affine[[i,l,s]],
{s,1,n}],
{i,1,n},{j,1,n},{k,1,n},{l,1,n}] ]//Simplify;
ricci=Simplify[Table[Sum[riemann[[i,j,i,l]],{i,1,n}],{j,1,n},{l,1,n}] ]//Simplify;

scalar=Simplify[Sum[inversemetric[[i,j]]ricci[[i,j]],{i,1,n},{j,1,n}] ]//Simplify;
scalar